Ran multiple accounts, well... used to

Support
11

Solution for steam & unity:

Now it uses registry entries instead of files. If you had your accounts linked/registered before you can use this method with a batch below:

----------begin

@echo off
REM set your SteamLibrary-path here
set adr=D:\Games\SteamLibrary\
REM set default seconds for timer
set def=5

IF NOT EXIST %adr%last.run goto select
set /p lastsel=<%adr%last.run
call :trim %lastsel%
regedit /e %adr%Op%sel%.reg "HKEY_CURRENT_USER\Software\Pipeworks\GemsofWar"

:select
echo.
echo.
echo  Select GoW-Account:
REM add/edit your accounts 
echo    1  MUMOREX
echo    2  MUMOREX ftp
echo    3  ARCHIS
echo.
REM edit/adjust the options after /C
choice /T %def% /C 123 /D 1 /M "Your choice (default 1 after %def% sec): "

set sel=%errorlevel%

IF NOT EXIST %adr%Op%sel%.reg goto steam
regedit /s %adr%Op%sel%.reg

:steam
echo %sel% >%adr%last.run
REM set your Steam-path here, if not used default setup
"C:\Program Files (x86)\Steam\Steam.exe" -applaunch 329110
exit


:trim
set sel=%1

----------end

You need to save the code between begin & end as a file with suffix .bat (eg GoW_Select.bat)

Adjust the code below the REM lines and run this file as Administrator.

  • Tip: create a windows shortcut for this bat-file and go to properties and set in “advanced” to run as admin.

Important for the initialization:

  1. start GoW with this batch and select your default (1) account and quit GoW

  2. start now again and select your 2nd account. You will be in your main (1). Now go to settings and link your 2nd account and quit GoW

  3. repeat step 2 for more accounts, if you have…

Daily use

once intitialized, you can start the batch and select your account by typing the number.

hope this helps

5 Likes